Skip to main content

闪电贷

什么是闪电贷​

简单来说，闪电贷就是在一个区块交易中，同时完成借款和还款操作这两个操作，无需抵押任何资产，只需支付手续费即可。 用户在借到款之后，可以利用借到的资产进行其他操作，然后在交易结束的时候，用户只要把借到的款项及手续费及时归还就可以，否则该笔交易就会回滚，就像什么也没有发生过一样。

常见的闪电贷方式

目前市面上主流的几种提供闪电贷业务的 DeFi 项目，主要有 Aave、Uniswap、dYdX 等。Aave 是最早将闪电贷进行实际应用的 DeFi 协议.

FlashLoan​

FlashSwap​

Uniswap等 DEX 平台提供了Flash Swap等功能。

闪电贷和闪电兑换均采用称为”乐观转账“的技术。这个了不起的 DeFi 创新技术使用户可以进行 无抵押贷款或兑换交易，只要用户在交易结束时还清借款，就可以执行交易。下面以Uniswap为例

FlashSwap执行的整个步骤

  1. 借贷方可以先向合约借贷 x, y token 中某一个（或者两个都借贷）
  2. 借贷方指定借贷的数量，以及回调函数的参数，调用 flashswap
  3. 合约会先将用户请求借贷的 token 按指定数量发送给借贷方
  4. 发送完毕后，Uniswap Pair 合约会向借贷方指定的合约的地址调用指定的回调函数，并将回调函数的参数传入
  5. 调用完成后，Uniswap Pair 合约检查 x, y token 余额满足 x′⋅y′≥k

UniswapV2​

UniswapV2中的swap方法允许两种类型的贷款 例如: TokenA/TokenB交易对

  1. 借TokenA还TokenA
  2. 借TokenA还TokenB

UniswapV3​

  • 借款 Token 和还款 Token 相同，使用UniswapV3Pool.flash()方法
  • 借款 Token 和还款 Token 不同，使用UniswapV3Pool.swap()方法

Uniswap的UniswapV2Pair.sol合约

// this low-level function should be called from a contract which performs important safety checks
function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external lock {
    require(amount0Out > 0 || amount1Out > 0, 'UniswapV2: INSUFFICIENT_OUTPUT_AMOUNT');
    (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
    require(amount0Out < _reserve0 && amount1Out < _reserve1, 'UniswapV2: INSUFFICIENT_LIQUIDITY');

    uint balance0;
    uint balance1;
    { // scope for _token{0,1}, avoids stack too deep errors
        address _token0 = token0;
        address _token1 = token1;
        require(to != _token0 && to != _token1, 'UniswapV2: INVALID_TO');
        // 乐观转账给借款人
        if (amount0Out > 0) _safeTransfer(_token0, to, amount0Out); // optimistically transfer tokens
        if (amount1Out > 0) _safeTransfer(_token1, to, amount1Out); // optimistically transfer tokens
        // 借款合约需要提供uniswapV2Call方法，进行还款。借款合约在该方法中执行借款后的逻辑和还款逻辑
        if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);
        // 还款以后，合约会读取当前交易对的余额
        balance0 = IERC20(_token0).balanceOf(address(this));
        balance1 = IERC20(_token1).balanceOf(address(this));
    }
    uint amount0In = balance0 > _reserve0 - amount0Out ? balance0 - (_reserve0 - amount0Out) : 0;
    uint amount1In = balance1 > _reserve1 - amount1Out ? balance1 - (_reserve1 - amount1Out) : 0;
    require(amount0In > 0 || amount1In > 0, 'UniswapV2: INSUFFICIENT_INPUT_AMOUNT');
    { // scope for reserve{0,1}Adjusted, avoids stack too deep errors
        uint balance0Adjusted = balance0.mul(1000).sub(amount0In.mul(3));
        uint balance1Adjusted = balance1.mul(1000).sub(amount1In.mul(3));
        // 校验这笔交易是否满足要求。如果上面借款没有足额还款，这里校验会失败
        require(balance0Adjusted.mul(balance1Adjusted) >= uint(_reserve0).mul(_reserve1).mul(1000**2), 'UniswapV2: K');
    }

    _update(balance0, balance1, _reserve0, _reserve1);
    emit Swap(msg.sender, amount0In, amount1In, amount0Out, amount1Out, to);
}

参考资料​